2001 Cummins ECU + Arduino Mega + CCD/PCI devboard

[jlaustill]

Is there any reason this library wouldn't work on an Arduino Due? I'm setting out to write an OPCM(Opensource Powertrain Communication Module) and one of my needs is communicating with the CCD network on a Cummins ECM. I will also be outputting standard Tachometer and Speedometer signals(for use with my cruise control, tranny controller, exhaust break, etc) and broadcasting on OBDII via canbus. Putting all these pieces together is going to be fun, but also requires leaning on the previous work of others like you and this amazing-looking library! Before I go and order hardware(I currently only have Uno's) I want to plan ahead a bit. Also, any pointers on the best sources for the hardware required for this library would be great :)

[laszlodaniel]

The main issue is that CCD-bus circuits and logics derive from 5V and Due operates at 3.3V.
Then the library is hardcoded to use Arduino Mega's UART1, Timer1 and a few external interrupt capable pins. This is a smaller issue since the library can be supplemented with Due pin definitions.
Still the devboard I currently develop depends on 5V voltage source and logic.

The CCD/PCI transceiver devboard is available here.

Are you bound to use Arduino Due?

[laszlodaniel]

Something is going on with the CAN-bus transmission. It shouldn't affect engine management.

I think it's better to start from scratch, my SCI-bus routine became too complicated lately.
Here's a basic SCI-bus handler that requests fault codes every 2 seconds and prints the result to Arduino Serial Monitor.
You should see the command itself echoed back (32), then the fault codes and probably a checksum value at the end. These are standard OBD2 P-codes, numerical values only.

// Basic SCI-bus handler

#define ARRAY_SIZE(A) (sizeof(A) / sizeof((A)[0]))

uint8_t SCIRxBuffer[16];
uint8_t SCIRxBufferPtr = 0;
uint8_t lastMessageLength = 0;

uint8_t SCIBusSpeed = 0; // 0 = 7812.5, 1 = 62500

uint8_t faultCodeRequest[1] = { 0x32 };
uint16_t faultCodeRequestInterval = 2000; // ms
uint32_t lastFaultCodeRequestMillis = 0;

uint32_t currentMillis = 0;

void setLowSpeedMode()
{
    Serial2.flush();
    UBRR2L = 127; // 7812.5 baud @ 16 MHz
    SCIBusSpeed = 0;
}

void setHighSpeedMode()
{
    Serial2.flush();
    UBRR2L = 15; // 62500 baud @ 16 MHz
    SCIBusSpeed = 1;
}

void handleSerialCommands()
{
    if (Serial.available() > 0)
    {
        // TODO
    }
}

void requestFaultCodes()
{
    if (SCIBusSpeed == 0)
    {
        currentMillis = millis();

        if ((uint32_t)(currentMillis - lastFaultCodeRequestMillis) >= faultCodeRequestInterval)
        {
            lastFaultCodeRequestMillis = currentMillis;
            Serial2.write(faultCodeRequest, ARRAY_SIZE(faultCodeRequest));
        }
    }
}

void handleSCIBus()
{
    if (Serial2.available() > 0)
    {
        SCIRxBufferPtr = 0;

        while (Serial2.available())
        {
            uint8_t c = Serial2.read(); // read next byte
            SCIRxBuffer[SCIRxBufferPtr] = c; // store byte in buffer
            SCIRxBufferPtr++; // increment pointer value
        }

        lastMessageLength = SCIRxBufferPtr;

        for (uint8_t i = 0; i < lastMessageLength; i++)
        {
            if (SCIRxBuffer[i] < 16) Serial.print("0"); // print leading zero
            Serial.print(SCIRxBuffer[i], HEX); // print message byte in hexadecimal format on the serial monitor
            Serial.print(" "); // insert whitespace between bytes
        }

        Serial.println(); // add new line
    }
}

void setup()
{
    Serial.begin(250000); // USB
    Serial2.begin(250000); // SCI-bus (RX2/TX2)
    setLowSpeedMode();
}

void loop()
{
    handleSerialCommands();
    handleSCIBus();
    requestFaultCodes();
}

[jlaustill]

Well, this got me getting messages! Now I need to figure out how to make sense of them. I played with this ALL day with zero luck, and then it hit me, maybe I fried my arduino pins, so I switched to rx1/tx1 and bam, messages! Then I tried to switch to high speed mode and at first I was getting a 12 response, then I updated my code and I wasn't. But then I started seeing Fxx messages, so I assumed the ECU switched and I started sending the RPM request and it was giving me more back, but nothing I could make sense of. I have a feeling there's something up with the receiving end after seeing in the mopar forum that some 01 and 02 dodge owners have this same issue with scanners where they work sometimes and not others. SO frustrating :(

#include <Arduino.h>

// Basic SCI-bus handler

#define ARRAY_SIZE(A) (sizeof(A) / sizeof((A)[0]))

uint8_t SCIRxBuffer[16];
uint8_t SCIRxBufferPtr = 0;
uint8_t lastMessageLength = 0;

uint8_t SCIBusSpeed = 0; // 0 = 7812.5, 1 = 62500

uint8_t faultCodeRequest[1] = { 0x32 };
uint8_t highSpeedRequest[1] = { 0x12 };
uint8_t rpmRequest[3] = { 0xFB, 0x0a, 0x02 };
uint16_t faultCodeRequestInterval = 2000; // ms
uint32_t lastFaultCodeRequestMillis = 0;

uint32_t currentMillis = 0;

void setLowSpeedMode()
{
    Serial1.flush();
    UBRR2L = 127; // 7812.5 baud @ 16 MHz
    SCIBusSpeed = 0;
}

void setHighSpeedMode()
{
    Serial1.flush();
    UBRR2L = 15; // 62500 baud @ 16 MHz
    SCIBusSpeed = 1;
}

void handleSerialCommands()
{
    if (Serial.available() > 0)
    {
        Serial.print("I received: ");
        // read the incoming byte:
        while(Serial.available()) {
            byte incomingByte = Serial.read();

            // say what you got:
            Serial.print(incomingByte);
            Serial.print(" ");
        }
        Serial.println();
    }
}

void requestFaultCodes()
{
    if (SCIBusSpeed == 0)
    {
        currentMillis = millis();

        if ((uint32_t)(currentMillis - lastFaultCodeRequestMillis) >= faultCodeRequestInterval)
        {
            lastFaultCodeRequestMillis = currentMillis;
            Serial1.write(faultCodeRequest, ARRAY_SIZE(faultCodeRequest));
            Serial.println();
            Serial.println("Requested fault codes");
        }
    }
}

void requestHighSpeed() {
    if (SCIBusSpeed == 0)
    {
        currentMillis = millis();

        if ((uint32_t)(currentMillis - lastFaultCodeRequestMillis) >= faultCodeRequestInterval)
        {
            lastFaultCodeRequestMillis = currentMillis;
            Serial1.write(highSpeedRequest, ARRAY_SIZE(highSpeedRequest));
            Serial.println();
            Serial.println("Requesting high speed");
        }
    }
}

void requestRpm() {
    if (SCIBusSpeed == 1) {
        currentMillis = millis();

        if ((uint32_t)(currentMillis - lastFaultCodeRequestMillis) >= faultCodeRequestInterval)
        {
            lastFaultCodeRequestMillis = currentMillis;
            Serial1.write(rpmRequest, ARRAY_SIZE(rpmRequest));
            Serial.println();
            Serial.println("Requesting rpm");
        }
    }
}

void handleSCIBus()
{
    if (Serial1.available() > 0)
    {
        Serial.println("We received a message in " + (String)(SCIBusSpeed == 1 ? "high speed " : "low speed ") + "mode!");
        SCIRxBufferPtr = 0;

        while (Serial1.available())
        {
            uint8_t c = Serial1.read(); // read next byte
            if (SCIRxBufferPtr++ == 0 && c == 0x12) {
                Serial.println("high speed set!");
                setHighSpeedMode();
            }
            Serial.print(c, HEX);
            Serial.print(" ");
//            SCIRxBuffer[SCIRxBufferPtr] = c; // store byte in buffer
//            SCIRxBufferPtr++; // increment pointer value
        }

//        lastMessageLength = SCIRxBufferPtr;

//        for (uint8_t i = 0; i < lastMessageLength; i++)
//        {
////            if (SCIRxBuffer[i] < 16) Serial.print("0"); // print leading zero
//            Serial.print(SCIRxBuffer[i], HEX); // print message byte in hexadecimal format on the serial monitor
//            Serial.print(" "); // insert whitespace between bytes
//        }

        Serial.println(); // add new line
    }
}

void setup()
{
    Serial.begin(115200); // USB
    Serial1.begin(115200); // SCI-bus (RX2/TX2)
    setLowSpeedMode();
    Serial.println("init'd");
}

void loop()
{
    handleSCIBus();

    if (SCIBusSpeed == 0) {
        requestHighSpeed();
        setHighSpeedMode();
    } else {
        requestRpm();
    }
//    Serial.println("New loop *******************************************");
//    handleSerialCommands();
//    requestFaultCodes();
    delay(200);
}

That's where I ended up for the day getting responses like this

Requesting rpm
We received a message in high speed mode!
F0 0 0 F0 0 F0 0 0 80 0 F0 0 
We received a message in high speed mode!
0 F0 0 0 0 F0 0 0 0 0 F0 0 
We received a message in high speed mode!
80 0 F0 0 0 F0 0 0 0 F0 0 F0 0 
We received a message in high speed mode!
F0 0 0 0 F0 0 0 F0 0 0 
We received a message in high speed mode!
0 0 0 F0 0 0 F0 0 0 F0 0 
We received a message in high speed mode!
0 0 F0 0 0 0 FE 0 0 0 
We received a message in high speed mode!
0 0 0 0 F0 0 0 F0 0 0 
We received a message in high speed mode!
0 E0 0 F0 0 F0 0 F0 0 C0 0 0 0 
We received a message in high speed mode!
F0 0 E0 0 F0 0 F8 0 0 E0 0 F0 0 0 
We received a message in high speed mode!
0 E0 0 F0 0 0 E0 0 0 0 F0 0 

Requesting rpm
We received a message in high speed mode!
0 E0 0 0 0 0 E0 0 0 F0 0 
We received a message in high speed mode!
0 0 0 F0 0 0 F0 0 0 0 

I'll let me roll around in my brain a bit and give it another shot later for sure, this is encouraging!

Also, the cummins bus is how the ECU communicates with the VP44 fuel pump it turns out, so anything you do on that can-bus network can confuse them both. My tuner reads data from it so I know it is possible, but without the specs and knowing it is possible to make it mad it seems scary to me :(

[jlaustill]

It just hit me, I was leaving the truck running, so once I sent 0x12 it stayed in high-speed mode when I updated my code 🤦 I'm learning, slowly...

[laszlodaniel]

Great!

In the speed change functions change the baudrate registers to UART1-channel too: UBRR2L -> UBRR1L

The engine speed request should be FB 01 02:
uint8_t rpmRequest[3] = { 0xFB, 0x01, 0x02 };

so once I sent 0x12 it stayed in high-speed mode

Yes, it stays there until you exit (FE) or cycle the key in the ignition switch.

anything you do on that can-bus network can confuse them both

Start simple. I don't know much about CAN-bus, but there is a simple request to get available PIDs, and probably you can just ping the ECM.

[goliva8115]

Hola. Muy interesante hilo, quisiera saber si fue posible realizar el proyecto. Gracias