NixOS Xorg "the requested operation is not supported by Winit"

[zax71]

Hi! I just cloned the Slint example project then tried building it on my NixOS system, and it spits out the below error:

Error: Other("Could not initialize backend.\nError from Winit backend: Error initializing winit event loop: the requested operation is not supported by Winit\nNo backends configured.")

Would someone know why this is? Looked around and saw people having this issue on Wayland but no one on Xorg

[tronical]

This is similar to #4786 . Indeed, I think #4146 applies as well: I suspect that there's a missing shared library in your setup. Could you try to run strace on the binary?

[zax71]

Running with RUST_BACKTRACE=1 or RUST_BACKTRACE=full doesn't differ the result.

[tronical]

Could you try running the binary through strace? That way we should be able to see which shared libraries winit tries to dlopen and help identify the missing ones.

[zax71]

Right, yesterday I must have been glancing at this stuff a little too much... At the bottom of the linked discussion there is this answer but I'll repeat it here.

# flake.nix
{
  description = "rust devshell";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs {
          inherit system overlays;
        };
      in
      {
        devShells.default =
          with pkgs;
          mkShell {
            buildInputs = [
              rust-bin.beta.latest.default
            ];

            LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${
              lib.makeLibraryPath [
                pkgs.xorg.libX11
                pkgs.xorg.libXcursor
                pkgs.xorg.libXi
                pkgs.wayland
                pkgs.libxkbcommon
                pkgs.fontconfig
              ]
            }";
          };
      }
    );
}

Then run nix develop and build the project with cargo run